dnl
dnl $Id: configure.in,v 1.400 2008/02/09 01:24:49 vanbaal Exp $
dnl
dnl Copyright (C) 2000, 2001, 2002, 2003, 2004 Stichting LogReport Foundation
dnl     LogReport@LogReport.org
dnl
dnl     This program is free software; you can redistribute it and/or modify
dnl     it under the terms of the GNU General Public License as published by
dnl     the Free Software Foundation; either version 2 of the License, or
dnl     (at your option) any later version.
dnl 
dnl     This program is distributed in the hope that it will be useful,
dnl     but WITHOUT ANY WARRANTY; without even the implied warranty of
dnl     MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
dnl     GNU General Public License for more details.
dnl 
dnl     You should have received a copy of the GNU General Public License
dnl     along with this program (see COPYING); if not, check with
dnl     http://www.gnu.org/copyleft/gpl.html. 
dnl
dnl Run autoscan to regenerate this file.
dnl After editing this file, run automake to regenerate Makefile.in's.
dnl
dnl Process this file with autoconf to produce a configure script.
AC_INIT()
AM_INIT_AUTOMAKE(lire, `cat $srcdir/VERSION`)

dnl this would allow to add a call to autopoint to ./boostrap, just before
dnl aclocal.   See the gettext info pages for more nice automake macros.
dnl
dnl "Gettext supplies the autopoint command to add translation infrastructure
dnl to a source package. If you use autopoint, your configure.ac should invoke
dnl both AM_GNU_GETTEXT and AM_GNU_GETTEXT_VERSION(gettext-version). See
dnl Invoking the autopoint Program, for further details."
dnl
dnl http://www.gnu.org/software/autoconf/manual/html_node/autoreconf-Invocation.html#index-Gettext-18
dnl http://www.gnu.org/software/gettext/manual/html_chapter/gettext_13.html#SEC194
dnl http://www.gnu.org/software/gettext/manual/html_chapter/gettext_12.html#SEC172
dnl
dnl for now, keep it commented out:
dnl AM_GNU_GETTEXT_VERSION(0.14.6)

dnl First determine if this is run to from CVS or from
dnl a tar.gz distribution
AC_MSG_CHECKING(if building from CVS)
if test -d CVS
then
    BUILDINGFROMCVS="yes"
else
    BUILDINGFROMCVS="no"
fi
AC_MSG_RESULT($BUILDINGFROMCVS)

AC_MSG_CHECKING(if CVS requirements should be ignored)
IGNOREBUILDINGFROMCVS="no"
AC_ARG_WITH(ignorecvsbuildcheck,
      [  --with-ignorecvsbuildcheck Don't fail on missing tools when
                          configurating from CVS],
      [
         IGNOREBUILDINGFROMCVS="yes"
      ]
            )
AC_MSG_RESULT($IGNOREBUILDINGFROMCVS)

AC_ARG_WITH(perl5libdir,
      [  --with-perl5libdir=DIR  where to install the Lire perl5 modules
                          [PREFIX/share/perl5] ],
      [  if test -n "$withval"
         then
          LR_PERL5LIBDIR="$withval"
         fi]
            )
dnl set default
if test -z "$LR_PERL5LIBDIR"
then
    if test "x$prefix" = xNONE
    then
        LR_PERL5LIBDIR="$ac_default_prefix/share/perl5"
    else
        LR_PERL5LIBDIR="$prefix/share/perl5"
    fi
fi
AC_SUBST(LR_PERL5LIBDIR)

AC_ARG_WITH(spooldir,
      [  --with-spooldir=DIR     where scripts should look for emails 
                          containing logfiles (only interesting if you plan 
                          to run your own responder) 
                          [PREFIX/var/spool/lire] ],
      [  if test -n "$withval"
         then
          LR_SPOOLDIR="$withval"
         fi]
            )
if test -z "$LR_SPOOLDIR"
then
    if test "x$prefix" = xNONE
    then
        LR_SPOOLDIR="$ac_default_prefix/var/spool/lire"
    else
        LR_SPOOLDIR="$prefix/var/spool/lire"
    fi
fi
AC_SUBST(LR_SPOOLDIR)


AC_ARG_WITH(archivedir,
      [  --with-archivedir=DIR   where to be merged reports, and to be
                          postprocessed logs should get archived.  (If you do
                          not set the environment variable LR_ARCHIVE, the
                          archive will not be used; LOCALSTATEDIR per default
                          is PREFIX/var).
                          [LOCALSTATEDIR/lib/lire/data] ],
      [  if test -n "$withval"
         then
          LR_ARCHIVEDIR="$withval"
         fi]
            )
if test -z "$LR_ARCHIVEDIR"
then
    if test "x$prefix" = xNONE
    then
        LR_ARCHIVEDIR="$ac_default_prefix/var/lib/lire/data"
    else
        LR_ARCHIVEDIR="$localstatedir/lib/lire/data"
    fi
fi
AC_SUBST(LR_ARCHIVEDIR)



dnl Checks for programs.
AC_PROG_AWK
dnl AC_PROG_CC
AC_PROG_INSTALL
AC_PROG_LN_S
AC_PROG_MAKE_SET

AC_PATH_PROG(PERL, perl)
if test -z "$PERL"
then
        AC_MSG_ERROR(cannot find perl in your PATH.)
fi

AC_MSG_CHECKING(for perl >= 5.6.1)
if $PERL -e 'require 5.6.1' 2> /dev/null
then
    AC_MSG_RESULT(yes)
else
    AC_MSG_ERROR(no (Perl 5.6.1 or later is required (5.8.2 recommended) to run Lire. ))
fi

dnl 
dnl ACLR_PERL_MODULE([module],[mandatory]{,[min_version],[package]})
dnl An autoconf macro to test for Perl modules.
dnl The "mandatory" parameter states whether the test should fail if the
dnl module is not found. It can take the values "yes" and "no".
dnl The "min_version" parameter is optional. The optional "package" parameter
dnl specifies a package name to be installed to obtain the desired module.
dnl

AC_DEFUN([ACLR_PERL_MODULE],
[
m4_if([$3],[],[
aclr_checking_string="for perl module $1";
aclr_use_string="use $1;";
m4_if([$4],[],[
aclr_install_string="Please install $1 before continuing";
],[
aclr_install_string="Please install $4 before continuing";
])],[
aclr_checking_string="for perl module $1 >= $3";
aclr_use_string="use $1 $3;";
m4_if([$4],[],[
aclr_install_string="Please install $1 $3 or later before continuing";
],[
aclr_install_string="Please install $4 before continuing";
])])

AC_MSG_CHECKING([$aclr_checking_string])
if $PERL -e "$aclr_use_string" 2> /dev/null
then
    AC_MSG_RESULT([yes])
else
    m4_if([$2],[no],
          [AC_MSG_RESULT([no (you can install it later)])],
          [AC_MSG_RESULT([no

    $aclr_install_string
]);
exit 1;])
fi
])

AC_PATH_PROG(POD2MAN, pod2man)
if test -z "$POD2MAN"
then
        AC_MSG_ERROR(cannot find pod2man in your PATH.)
fi

dnl gettext support
AC_PATH_PROG(XGETTEXT, xgettext)
if test x"$BUILDINGFROMCVS" = x"yes" && \
        test x"$IGNOREBUILDINGFROMCVS" != x"yes"
then
    AC_MSG_CHECKING([for Perl support in xgettext])
    if $XGETTEXT --language=perl /dev/null 2> /dev/null
    then
        AC_MSG_RESULT(yes)
    else
        AC_MSG_ERROR([
        A Perl-enabled xgettext is required for building from CVS.
        Please install version 0.13 or later of the gettext package.
        Gettext can be downloaded from ftp://ftp.gnu.org/gnu/gettext/
        and is distributed with many Linux/BSD/Unix distributions.])
    fi
fi

AC_PATH_PROG(MSGFMT, msgfmt)
AC_PATH_PROG(MSGMERGE, msgmerge)

dnl /usr/sbin/sendmail on Linux and BSD's, /usr/lib/sendmail on Solaris
AC_PATH_PROG(SENDMAIL, sendmail, , $PATH:/usr/sbin:/usr/lib)
if test -z "$SENDMAIL"
then
    AC_MSG_ERROR(cannot find sendmail in $PATH:/usr/sbin nor /usr/lib.)
fi

AC_PATH_PROG(LOGGER, logger)
if test -z "$LOGGER"
then
    AC_MSG_ERROR(cannot find syslog's logger in your PATH.)
fi

dnl tar is used to include images with HTML and DocBook
AC_PATH_PROG(TAR, tar, no)

AC_PATH_PROG(GZIP, gzip, no)

dnl If this program is not found, Lire will search $PATH
dnl If it is then still not found Lire will issue a warning at runtime.
AC_PATH_PROG(TAI64NLOCAL, tai64nlocal, tai64nlocal)

dnl ploticus is /usr/local/bin/pl on FreeBSD (and other BSD's too, probably)
AC_PATH_PROGS(PLOTICUS, ploticus pl, no)
DEFAULT_IMAGE_STYLE=gd

AC_PATH_PROG(GHOSTSCRIPT, gs, no)
if test x"$GHOSTSCRIPT" = x"no" \
    && test x"$IGNOREBUILDINGFROMCVS" != x"yes" \
    && test x"$BUILDINGFROMCVS" = x"yes"
then
    AC_MSG_ERROR([
        GhostScript is required for building from CVS.
        It can be downloaded from http://www.cs.wisc.edu/~ghost/doc/gnu/ and is
        distributed with many Linux/BSD/Unix distributions.])
fi

dnl also check for: sort

dnl
dnl CHECKS FOR PERL MODULES
dnl

ACLR_PERL_MODULE(XML::Parser,yes)
ACLR_PERL_MODULE(DBI,yes)
ACLR_PERL_MODULE(DBD::SQLite2,yes)
ACLR_PERL_MODULE(Digest::MD5,yes)
ACLR_PERL_MODULE(Curses,yes,1.06)
ACLR_PERL_MODULE(Curses::UI,yes,0.92)
ACLR_PERL_MODULE(Locale::TextDomain,yes,,[the libintl-perl CPAN module])
ACLR_PERL_MODULE(Spreadsheet::WriteExcel,no)
ACLR_PERL_MODULE(MIME::Entity,no)

AC_MSG_CHECKING(for Time::Timezone)
if $PERL -MTime::Timezone -e 'exit 0' 2> /dev/null
then
    AC_MSG_RESULT(yes)
    INSTALL_TIMEZONE="no"
else
    AC_MSG_RESULT(no (will install included version))
    INSTALL_TIMEZONE="yes"
fi
AM_CONDITIONAL(INSTALL_TIMEZONE, test x$INSTALL_TIMEZONE = xyes)

dnl check for additional tools: jade, pdfjadetex, java, lynx

dnl used to build the DocBook documentation
AC_PATH_PROGS(JADE, jade openjade)
if test -z "$JADE" \
    && test x"$IGNOREBUILDINGFROMCVS" != x"yes" \
    && test x"$BUILDINGFROMCVS" = x"yes"
then
    AC_MSG_ERROR([
        Jade or OpenJade is required for building from CVS.
        Openjade can be downloaded from http://www.jclark.com/jade/ and is
        distributed with many Linux/BSD/Unix distributions.])
fi

dnl used to build the DocBook documentation
AC_PATH_PROGS(PDFJADETEX, pdfjadetex)
if test -z "$PDFJADETEX" \
    && test x"$IGNOREBUILDINGFROMCVS" != x"yes" \
    && test x"$BUILDINGFROMCVS" = x"yes"
then
    AC_MSG_ERROR([
        JadeTeX is required for building from CVS.
        It can be downloaded from http://jadetex.sourceforge.net/ and is
        distributed with many Linux/BSD/Unix distributions.])
fi

AC_PATH_PROG(XSLTPROC, xsltproc)
if test -n "$XSLTPROC"
then
    AC_MSG_CHECKING(xsltproc version >= 1.0.10)
    dnl xsltproc 0.7.0 does not give version with -V.  we need e.g.
    dnl libxslt 10010, aka libxslt 1.0.10
    xsltproc_version=`$XSLTPROC -V | $PERL -ne 'if (/libxslt (\d+)/) { print $1, "\n"; exit 0 }'`
    if test -n "$xsltproc_version" -a "$xsltproc_version" -ge 10010
    then
        AC_MSG_RESULT(yes ($xsltproc_version))
    else
        AC_MSG_RESULT(no ($xsltproc_version))
        XSLTPROC=
    fi
fi

if test -z "$XSLTPROC" \
    && test x"$IGNOREBUILDINGFROMCVS" != x"yes" \
    && test x"$BUILDINGFROMCVS" = x"yes"
then
    AC_MSG_ERROR([
        xsltproc 1.0.10 or later is required for building from CVS.
        It can be downloaded from http://xmlsoft.org/XSLT/ and is
        distributed with many Linux/BSD/Unix distributions.])
fi

# Used by the PDF output format
AC_PATH_PROG(LAMBDA, lambda, no)
AC_PATH_PROG(ODVIPS, odvips, no)
AC_PATH_PROG(PS2PDF, ps2pdf, no)

dnl this is only of use on RedHat plaforms now
AC_PATH_PROG(XMLCATALOG,xmlcatalog,no)

dnl used by: HTML2TXTRULE in include/rules.mk, which gets used in
dnl doc/Makefile, <superservice>/script/Makefile
AC_PATH_PROG(LYNX, lynx)
if test -z "$LYNX" \
    && test x"$IGNOREBUILDINGFROMCVS" != x"yes" \
    && test x"$BUILDINGFROMCVS" = x"yes"
then
    AC_MSG_ERROR([
        Lynx is required for building from CVS.
        It can be downloaded from http://lynx.isc.org/ and is
        distributed with many Linux/BSD/Unix distributions.])
fi

dnl Try to find the SGML directory layout
dnl Find a list of potential SGML/XML trees, we will look into subdirectories
dnl of this one to find the DSSSL/DTD/XSLT stuff.
sgmldirs=""
try_dirs="/usr/lib/sgml /usr/share/sgml /usr/local/lib/sgml /usr/local/share/sgml /usr/share/xml /usr/local/share/xml /usr/local/share/xsl /usr/share/xml"
if test x"$prefix" != "xNONE"
then
    try_dirs="$try_dirs $prefix/lib/sgml $prefix/share/sgml $prefix/share/xml"
fi
AC_MSG_CHECKING(for SGML/XML trees)
for d in $try_dirs
do
    if test -d $d
    then
	if echo "$sgmldirs" | grep $d > /dev/null
	then
	    :
	else
	    sgmldirs="$sgmldirs $d"
	fi
    fi
done
if test -z "$sgmldirs"
then
    sgmldirs="none"
fi
AC_MSG_RESULT($sgmldirs)

dnl used by: <superservice>/script/catalog.in
dnl lr_xslt (which is used by lr_xml2[x]html, a.o.), lr_xml2pdf
AC_ARG_WITH(docbookx-dtd,
      [  --with-docbookx-dtd=DIR   suggest where the DocBook XML DTD is located ],
      [  if test -n "$withval"
         then
          DBK_XML_DTD="$withval"
         fi]
            )
AC_MSG_CHECKING(for DocBook XML DTD)
if test -z "$DBK_XML_DTD"
then
dnl If xmlcatalog is available and the /etc/xml/catalog
dnl is present, we assume we are working with a sane XML environment
dnl and in this case, its the base way to find the location of this
dnl DTD
    if test "x$XMLCATALOG" != "xno" && test -f /etc/xml/catalog
    then
        DTD=`$XMLCATALOG /etc/xml/catalog "-//OASIS//DTD DocBook XML V4.1.2//EN"`
	if echo "$DTD" |grep '^file://' >/dev/null 2>/dev/null
	then
	    DBK_XML_DTD=`echo "$DTD" | sed -e 's|^file://||'`
	    AC_MSG_RESULT($DBK_XML_DTD)
	else
	    AC_MSG_RESULT(no)
	fi
    else
        for d in $sgmldirs
	do
	    for f in docbkx412 xml/4.1.2 xml-dtd-4.1.2 4.1.2
	    do
		if test -f "$d/dtd/$f/docbookx.dtd"
		then
		    DBK_XML_DTD="$d/dtd/$f/docbookx.dtd"
		    AC_MSG_RESULT($DBK_XML_DTD)
		elif test -f "$d/docbook/dtd/$f/docbookx.dtd"
		then
		    DBK_XML_DTD="$d/docbook/dtd/$f/docbookx.dtd"
		    AC_MSG_RESULT($DBK_XML_DTD)
		elif test -f "$d/$f/docbookx.dtd"
		then
		    DBK_XML_DTD="$d/$f/docbookx.dtd"
		    AC_MSG_RESULT($DBK_XML_DTD)
		elif test -f "$d/docbook/$f/docbookx.dtd"
		then
		    DBK_XML_DTD="$d/docbook/$f/docbookx.dtd"
		    AC_MSG_RESULT($DBK_XML_DTD)
		fi
		test -n "$DBK_XML_DTD" && break
	    done
	    test -n "$DBK_XML_DTD" && break
	done
        if test -z "$DBK_XML_DTD"
        then
            AC_MSG_RESULT(no)
        fi 
    fi
else
    AC_MSG_RESULT($DBK_XML_DTD)
    if test -f "$DBK_XML_DTD"
    then
        :
    else
	AC_MSG_WARN($DBK_XML_DTD isn't present on the system)
    fi
fi

if test -z "$DBK_XML_DTD" \
    && test x"$IGNOREBUILDINGFROMCVS" != x"yes" \
    && test x"$BUILDINGFROMCVS" = x"yes"
then
    AC_MSG_ERROR([
        The DocBook XML 4.1.2 DTD is required for building from CVS.
        It can be downloaded from http://docbook.sf.net/ and is
        distributed with many Linux/BSD/Unix distributions.])
fi
AC_SUBST(DBK_XML_DTD)

dnl Debian GNU/Linux woody has
dnl /usr/lib/sgml/stylesheet/dsssl/docbook/nwalsh/print/docbook.dsl
dnl Red Hat 7.1 has
dnl /usr/share/sgml/docbook/dsssl-stylesheets-1.59/print/docbook.dsl

dnl used by: lr_xml2html, lr_xml2pdf
AC_MSG_CHECKING(for DocBook DSSSL stylesheets)
if test -z "$DBK_DSSSL_STYLESHEETS" && test -z "$DBKDSSSLPRINT"
then
    for d in $sgmldirs
    do
	for f in stylesheet/dsssl/docbook stylesheet/dsssl stylesheet docbook/dsssl docbook/stylesheet/dsssl docbook/dsssl-stylesheets stylesheets/dsssl/docbook
	do
	    if test -f "$d/$f/print/docbook.dsl"
	    then
		AC_MSG_RESULT("$d/$f")
		DBKDSSSLPRINT="$d/$f/print/docbook.dsl"
	    elif test -f "$d/$f/modular/print/docbook.dsl"
	    then
		AC_MSG_RESULT("$d/$f/modular")
		DBKDSSSLPRINT="$d/$f/modular/print/docbook.dsl"
	    elif test -f "$d/$f/nwalsh/print/docbook.dsl"
	    then
		AC_MSG_RESULT("$d/$f/nwalsh")
		DBKDSSSLPRINT="$d/$f/nwalsh/print/docbook.dsl"
	    fi
            test -n "$DBKDSSSLPRINT" && break
	done
        test -n "$DBKDSSSLPRINT" && break
    done
    if test -z "$DBKDSSSLPRINT"
    then
        AC_MSG_RESULT(no)
    fi 
else
    if test -n "$DBK_DSSSL_STYLESHEETS"
    then
        DBKDSSSLPRINT="$DBK_DSSSL_STYLESHEETS/print/docbook.dsl"
        AC_MSG_RESULT($DBK_DSSSL_STYLESHEETS)
        if test ! -d "$DBK_DSSSL_STYLESHEETS"
	then
	    AC_MSG_WARN($DBK_DSSSL_STYLESHEETS isn't present on system)
	fi
    else
	AC_MSG_RESULT($DBKDSSSLPRINT)
	if test ! -f "$DBKDSSSLPRINT"
	then
	    AC_MSG_WARN($DBKDSSSLPRINT isn't present on system)
	fi
    fi
fi

if test -z "$DBKDSSSLPRINT" \
    && test x"$IGNOREBUILDINGFROMCVS" != x"yes" \
    && test x"$BUILDINGFROMCVS" = x"yes"
then
    AC_MSG_ERROR([
        The DocBook DSSSL stylesheets are required for building from CVS.
        They can be downloaded from http://docbook.sf.net/ and are
        distributed with many Linux/BSD/Unix distributions.])
fi
AC_SUBST(DBKDSSSLPRINT)

AC_MSG_CHECKING(for DocBook XSL stylesheets)
if test -z "$DBK_XSL_STYLESHEETS" && test -z "$DBKXSLHTML"
then
    for d in $sgmldirs
    do
	for f in stylesheet/xsl/docbook stylesheet/xsl stylesheet docbook/stylesheet/xsl docbook/xsl docbook docbook/xsl-stylesheets docbook/stylesheet
	do
	    dir=
            if test -f "$d/$f/html/docbook.xsl"
	    then
		dir="$d/$f"
	    elif test -f "$d/$f/modular/html/docbook.xsl"
	    then
		dir="$d/$f/modular"
	    elif test -f "$d/$f/nwalsh/html/docbook.xsl"
	    then
		dir="$d/$f/nwalsh"
	    fi
	    if test -n "$dir"
	    then
		AC_MSG_RESULT("$dir")
		DBKXSLHTML="$dir/html/chunk.xsl"
		DBKXSLHTMLNOCHUNK="$dir/html/docbook.xsl"
		DBKXSLFO="$dir/fo/docbook.xsl"
	    fi
	    test -n "$DBKXSLHTML" && break
	done
	test -n "$DBKXSLHTML" && break
    done
    if test -z "$DBKXSLHTML"
    then
        AC_MSG_RESULT(no)
    fi 
else
    if test -n "$DBK_XSL_STYLESHEETS"
    then
	AC_MSG_RESULT($DBK_XSL_STYLESHEETS)
	if test ! -d "$DBK_XSL_STYLESHEETS"
	then
	    AC_MSG_WARN($DBK_XSL_STYLESHEETS isn't present on the system)
	fi
	DBKXSLHTML="$DBK_XSL_STYLESHEETS/html/chunk.xsl"
	DBKXSLHTMLNOCHUNK="$DBK_XSL_STYLESHEETS/html/docbook.xsl"
	DBKXSLFO="$DBK_XSL_STYLESHEETS/fo/docbook.xsl"
    else
	AC_MSG_RESULT($DBKXSLHTML)
	AC_MSG_RESULT($DBKXSLHTMLNOCHUNK)
	AC_MSG_RESULT($DBKXSLFO)

	if test ! -f "$DBKXSLHTML"
	then
	    AC_MSG_WARN($DBKXSLHTML isn't present on system)
	fi
    fi
fi

if test -z "$DBKXSLHTML" \
    && test x"$IGNOREBUILDINGFROMCVS" != x"yes" \
    && test x"$BUILDINGFROMCVS" = x"yes"
then
    AC_MSG_ERROR([
        The DocBook XSLT stylesheets are required for building from CVS.
        They can be downloaded from http://docbook.sf.net/ and are
        distributed with many Linux/BSD/Unix distributions.])
fi
AC_SUBST(DBKXSLHTML)
AC_SUBST(DBKXSLHTMLNOCHUNK)

dnl The following tools are only needed when building from the CVS
dnl to generate the documentation.
AC_PATH_PROG(DIA, dia)
if test -z "$DIA" \
    && test x"$IGNOREBUILDINGFROMCVS" != x"yes" \
    && test x"$BUILDINGFROMCVS" = x"yes"
then
    AC_MSG_ERROR([
        Dia is required for building from CVS.
        It can be downloaded from http://www.lysator.liu.se/~alla/dia/.])
fi

AC_PATH_PROG(XMLLINT, xmllint)
if test -z "$XMLLINT" \
    && test x"$IGNOREBUILDINGFROMCVS" != x"yes" \
    && test x"$BUILDINGFROMCVS" = x"yes"
then
    AC_MSG_ERROR([
        xmllint is required for building from CVS and is
        part of the libxslt package (along with xsltproc).])
fi

if test -n "$XMLLINT"
then
    AC_MSG_CHECKING(xmllint version >= 2.4.19)
dnl libxslt 20419, aka libxslt 2.4.19
    xmllint_version=`$XMLLINT --version 2>&1 | $PERL -ne 'if (/libxml version (\d+)/) { print $1, "\n"; exit 0 }'`
    if test -n "$xmllint_version" -a "$xmllint_version" -ge 20419
    then
        AC_MSG_RESULT(yes ($xmllint_version))
    else
        AC_MSG_RESULT(no ($xmllint_version))
        AC_MSG_WARN(xmllint from libxml 2.4.19 is advised for building from CVS)
    fi
fi

dnl Checks for libraries.


dnl Checks for header files.
dnl AC_HEADER_STDC
dnl AC_CHECK_HEADERS(unistd.h)



dnl Checks for typedefs, structures, and compiler characteristics.
dnl AC_TYPE_OFF_T
dnl AC_STRUCT_TM

dnl Checks for library functions.

dnl Files which gets variables substitued by configure.
dnl
dnl VERY IMPORTANT : Put the Makefile of a directory before
dnl its subdirectories. i.e
dnl
dnl  all/Makefile
dnl  all/etc/Makefile
dnl
dnl and not
dnl
dnl  all/etc/Makefile
dnl  all/Makefile
dnl
AC_OUTPUT([
   catalog
   catalog.xml
   Makefile
   all/Makefile
   all/etc/Makefile
   all/etc/defaults
   all/etc/profile_lean
   all/lib/Makefile
   all/lib/Lire/Makefile
   all/lib/Lire/ChartTypes/Makefile
   all/lib/Lire/Config/Makefile
   all/lib/Lire/Config/Build.pm
   all/lib/Lire/OutputFormats/Makefile
   all/lib/Lire/Report/Makefile
   all/lib/Lire/ReportParser/Makefile
   all/lib/Lire/SQLExt/Makefile
   all/lib/Lire/Test/Makefile
   all/lib/Lire/UI/Makefile
   all/lib/Firewall/Makefile
   all/lib/config-spec/Makefile
   all/lib/html/Makefile
   all/lib/tests/Makefile
   all/lib/tests/helpers/Makefile
   all/lib/tests/helpers/oldconverter2dlf
   all/lib/tests/po/Makefile
   all/lib/xml/Makefile
   all/lib/xml/dtd/Makefile
   all/man/Makefile
   all/po/Makefile
   all/script/configvars
   all/script/Makefile
   all/script/lire
   all/script/lr_anonymize
   all/script/lr_anondump
   all/script/lr_check_service
   all/script/lr_check_superservice
   all/script/lr_cron
   all/script/lr_deanonymize
   all/script/lr_desyslog
   all/script/lr_env
   all/script/lr_environment
   all/script/lr_functions
   all/script/lr_getbody
   all/script/lr_gsconvert
   all/script/lr_log2mail
   all/script/lr_log2report
   all/script/lr_mail
   all/script/lr_processmail
   all/script/lr_rawmail2mail
   all/script/lr_report_cfg2xml
   all/script/lr_run
   all/script/lr_setup_responder
   all/script/lr_spec2pot
   all/script/lr_spool
   all/script/lr_spoold
   all/script/lr_vendor_cron
   all/script/lr_xml2report
   all/script/lr_xml2mail
   all/script/subst-configvars
   all/schemas/Makefile
   database/Makefile
   database/script/Makefile
   database/script/mysql2dlf
   database/script/pgsql2dlf
   database/po/Makefile
   dialup/Makefile
   dialup/script/Makefile
   dialup/script/isdnlog2dlf
   dialup/po/Makefile
   dns/Makefile
   dns/script/Makefile
   dns/script/bind8_query2dlf
   dns/script/bind9_query2dlf
   dns/script/tinydns2dlf
   dns/po/Makefile
   dnszone/Makefile
   dnszone/script/Makefile
   dnszone/script/bind8_named2dlf
   dnszone/po/Makefile
   doc/Makefile
   doc/examples/Makefile
   email/Makefile
   email/script/Makefile
   email/script/argomail2dlf
   email/script/exim2dlf
   email/script/nms2dlf
   email/script/postfix2dlf
   email/script/postfix2dlf_main
   email/script/postfix2dlf_pre
   email/script/qmail2dlf
   email/script/s1ms2dlf
   email/script/sendmail2dlf
   email/po/Makefile
   extras/Makefile
   extras/Time/Makefile
   firewall/Makefile
   firewall/lib/Makefile
   firewall/script/Makefile
   firewall/script/cisco_ios2dlf
   firewall/script/fw1_lea2dlf
   firewall/script/pix2dlf
   firewall/script/snort2dlf
   firewall/script/welf2dlf
   firewall/po/Makefile
   ftp/Makefile
   ftp/lib/Makefile
   ftp/script/Makefile
   ftp/script/xferlog2dlf
   ftp/po/Makefile
   msgstore/Makefile
   msgstore/lib/Makefile
   msgstore/script/Makefile
   msgstore/script/dbmail2dlf
   msgstore/script/nmsmmp2dlf
   msgstore/script/nmsstore2dlf
   msgstore/po/Makefile
   print/Makefile
   print/po/Makefile
   proxy/Makefile
   proxy/lib/Makefile
   proxy/script/Makefile
   proxy/script/ms_isa2dlf
   proxy/script/welf_proxy2dlf
   proxy/po/Makefile
   spamfilter/Makefile
   spamfilter/script/Makefile
   spamfilter/script/spamassassin2dlf
   spamfilter/po/Makefile
   syslog/Makefile
   syslog/script/Makefile
   syslog/script/syslog2dlf
   syslog/po/Makefile
   www/Makefile
   www/script/Makefile
   www/script/combined2dlf
   www/script/common2dlf
   www/script/modgzip2dlf
   www/script/referer2dlf
   www/script/w3c_extended2dlf
   www/po/Makefile
])